// RGB2montage.txt macro for ImageJ
//
// This macro batch processes a folder of images including the sub-directory.
// All the images must be in RGB TIFF format.
// This macro will generate individual channel-view of the RGB file,
// and make montage of both the original and the channel-view of the image.
// The outputs start with M#-, which will be treated differently with original files,
// and will be over-written when you re-run the macro.
// 
// Author: cail @ cail.cn Jun 3 2005

requires("1.34m");

var channelnumber = 2;
Dialog.create("Use RGB2montage macro");
Dialog.addMessage("The selected directory should contain only RGB files.");
Dialog.addMessage("The montage will align RGB red green blue channels in turn.");
Dialog.addMessage("");
Dialog.addChoice("        Channel Number:", newArray("2", "3"));
Dialog.show();
channelnumber = Dialog.getChoice();

dir = getDirectory("Choose the directory containing images");
listFiles(dir);

function listFiles(dir) {
	list = getFileList(dir);
	for (i=0; i<list.length; i++) {
		if (endsWith(list[i], "/")) {
			listFiles(""+dir+list[i]);
		}
		else {
			if (startsWith(list[i], "M#-")!=true) {
				var file = dir + list[i];
				var newfile = dir + "M#-" + list[i];
				if (channelnumber==2) 
					RGmontage(file);
				else if (channelnumber==3)
					RGBmontage(file);
				else
					exit("Error! Unsupport channel number.");
			}
		}
	}
}

function RGmontage(file) {
	open(file);
	run("RGB Split");
	close();
	run("Convert Images to Stack");
	run("Convert Stack to RGB");
	selectWindow("Stack");
	run("RGB Color");
	run("Concatenator ", "stack1=[Stack (RGB)] stack2=Stack title=[Concatenated]");
	run("Make Montage...", "columns=3 rows=1 scale=1 first=1 last=3 increment=1 border=0");
	save(newfile);
	close();
	close();
}

function RGBmontage(file) {
	open(file);
	run("RGB Split");
	run("Convert Images to Stack");
	run("Convert Stack to RGB");
	selectWindow("Stack");
	run("RGB Color");
	run("Concatenator ", "stack1=[Stack (RGB)] stack2=Stack title=[Concatenated]");
	run("Make Montage...", "columns=4 rows=1 scale=1 first=1 last=4 increment=1 border=0");
	save(newfile);
	close();
	close();
}